Control Flow and Subs

if ($score >= 90) {
    print "A\n";
} elsif ($score >= 80) {
    print "B\n";
} else {
    print "practice\n";
}

print "ok\n" if $ok;       # statement modifier

for my $item (@items) {
    print "$item\n";
}

for (my $i = 0; $i < @items; $i++) {
    print "$i: $items[$i]\n";
}

while (my $line = <STDIN>) {
    chomp $line;
    next if $line eq "";
    last if $line eq "quit";
}

next;                         # skip to next iteration
last;                         # break out of loop
redo;                         # restart current iteration without condition

use v5.36;

sub greet ($name, $greeting = "Hello") {
    return "$greeting, $name";
}

sub total (@nums) {           # slurpy trailing array
    my $sum = 0;
    $sum += $_ for @nums;
    return $sum;
}

sub configure (%opts) {       # slurpy trailing hash
    return $opts{port} // 3000;
}

say greet("Ada");             # Hello, Ada

sub greet {
    my ($name) = @_;
    return "Hello, $name";
}

my $outer = 1;                # lexical: visible to end of enclosing block/file
sub f {
    my $inner = 2;            # visible only inside f
    return $outer + $inner;
}

sub next_id {
    state $id = 0;            # initialized once, persists across calls
    return ++$id;             # state needs use v5.10+ or use feature 'state'
}

{
    local $/;                 # slurp mode inside this block only
    my $content = <$fh>;
}

{
    local $ENV{TZ} = 'UTC';   # works on hash/array elements too
    run_report();
}

my @all = get_items();        # list context
my $n = @items;               # array in scalar context yields its length
my $count = () = $s =~ /x/g;  # count matches via forced list context

sub flexible {
    return wantarray ? (1, 2, 3) : "scalar";
    # wantarray: true in list context, false in scalar, undef in void
}

# classic: eval + $@ (works everywhere)
my $result = eval { risky() };
if ($@) {
    warn "failed: $@";        # check $@ immediately after eval
}

die "no config file\n";       # trailing \n suppresses "at line N"
die { code => 404 };          # die with a ref for structured errors

use v5.40;

try {
    risky();
}
catch ($e) {
    warn "failed: $e";
}

use Try::Tiny;

try {
    risky();
} catch {
    warn "failed: $_";        # the error is in $_
} finally {
    cleanup();
};                            # trailing semicolon required